AltitudeBot/build.gradle.kts

plugins {
    id("java")
    id("org.springframework.boot") version("3.5.3")
    id("io.spring.dependency-management") version "1.1.5"
    id("maven-publish")
    id("com.github.johnrengelman.shadow") version "8.1.1"
    id("com.github.ben-manes.versions") version "0.52.0"
}

group = "com.alttd"
version = "1.0.0-SNAPSHOT"
description = "Altitude Discord Bot."

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
    }
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components["java"])
        }
    }
}

tasks {
    withType<JavaCompile> {
        options.encoding = Charsets.UTF_8.name()
    }

    withType<Javadoc> {
        options.encoding = Charsets.UTF_8.name()
    }

    bootJar {
        enabled = false // Disable the bootJar task
    }

    jar {
        enabled = true // Enable the jar task
        manifest {
            attributes["Main-Class"] = "com.alttd.AltitudeBot"
        }
    }

    shadowJar {
        archiveFileName.set(rootProject.name + ".jar")
        mergeServiceFiles()
        manifest {
            attributes["Main-Class"] = "com.alttd.AltitudeBot" // Set your main class directly
        }
    }

    build {
        dependsOn(shadowJar)
    }
}

dependencies {
    // JDA
    implementation("net.dv8tion:JDA:6.1.1") {
        exclude("opus-java") // exclude audio
    }
    // MySQL
    implementation("mysql:mysql-connector-java:8.0.33")

    // Configurate
    implementation("org.spongepowered:configurate-yaml:4.2.0")

    // Excel
    implementation("org.apache.poi:poi:5.4.1")
    implementation("org.apache.poi:poi-ooxml:5.4.1")
    // Other stuff?
    compileOnly("org.projectlombok:lombok:1.18.38")
    annotationProcessor("org.projectlombok:lombok:1.18.38")
    implementation("com.alttd:AltitudeLogs:1.0")
    implementation("org.springframework.boot:spring-boot-starter-web:3.5.3")
    implementation("org.springframework.boot:spring-boot-starter-validation:3.5.3")
    implementation("com.google.code.gson:gson:2.13.1")

    testImplementation(platform("org.junit:junit-bom:5.13.1"))
    testImplementation("org.junit.jupiter:junit-jupiter")
}