Boosters/plugin/build.gradle.kts

plugins {
    `maven-publish`
    id("io.github.goooler.shadow")
    id("net.minecrell.plugin-yml.bukkit") version "0.5.1"
}

dependencies {
    // API
    implementation(project(":boosters-api"))
    // Galaxy
    compileOnly("com.alttd.cosmos:cosmos-api:1.21.6-R0.1-SNAPSHOT") {
        isChanging = true
    }
    // MyPet
    compileOnly("de.keyle:mypet:3.12-SNAPSHOT")
    // mcMMO
    compileOnly("com.gmail.nossr50.mcMMO:mcMMO:2.2.004") {
        exclude("com.sk89q.worldguard")
    }

    //Jackson (json)
    compileOnly("com.fasterxml.jackson.core:jackson-core:2.8.8")
    compileOnly("com.fasterxml.jackson.core:jackson-annotations:2.8.8")
    compileOnly("com.fasterxml.jackson.core:jackson-databind:2.8.8")
}

tasks {

    shadowJar {
        archiveFileName.set("${project.name}-${project.version}.jar")
    }

    build {
        dependsOn(shadowJar)
    }

}

bukkit {
    name = rootProject.name
    main = "$group.BoostersPlugin"
    apiVersion = "1.21"
    authors = listOf("destro174", "akastijn")
    softDepend = listOf("MyPet", "mcMMO")
    commands {
        register("listboosters") {
            description = "Lists all active and queued boosters"
            permission = "boosters.list"
            usage = "/listboosters"
        }
    }
}