Easter/build.gradle.kts

plugins {
    id("java")
    id("maven-publish")
    id("com.github.ben-manes.versions") version "0.52.0"
    id("com.github.johnrengelman.shadow") version "8.1.1"
}

group = "com.alttd.easter"
version = "1.0-SNAPSHOT"
description = "Altitude's Easter plugin"

apply<JavaLibraryPlugin>()

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
    }
}

tasks {
    withType<JavaCompile> {
        options.encoding = Charsets.UTF_8.name()
    }

    withType<Javadoc> {
        options.encoding = Charsets.UTF_8.name()
    }

    jar {
        archiveFileName.set("${rootProject.name}.jar")
    }

    named<com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar>("shadowJar") {
        archiveFileName.set("${rootProject.name}.jar")
        mergeServiceFiles()
    }
    build {
        dependsOn("shadowJar")
    }

    processResources {
        filteringCharset = Charsets.UTF_8.name()
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
        filesMatching("plugin.yml") {
            expand(Pair("version", project.version))
        }
    }
}

dependencies {
    compileOnly("com.alttd.cosmos:cosmos-api:1.21.10-R0.1-SNAPSHOT") {
        isChanging = true
    }

    implementation("com.alttd.inventory_gui:InventoryGUI:1.1.5-20260201.231743-1") {
        isChanging = true
    }

    implementation("org.slf4j:slf4j-api:2.0.17")

    compileOnly("org.projectlombok:lombok:1.18.38")
    annotationProcessor("org.projectlombok:lombok:1.18.38")
}