PlayerShops/build.gradle.kts

import java.io.ByteArrayOutputStream

plugins {
    id("java")
    id("net.minecrell.plugin-yml.bukkit") version "0.5.1"
    id("com.github.johnrengelman.shadow") version "7.1.0"
}

allprojects {
    group = "com.alttd.playershops"
    version = "1.0-SNAPSHOT"
    description = "Player Shop plugin for Altitude."

    apply<JavaLibraryPlugin>()

    java {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(17))
        }
    }

    tasks {
        withType<JavaCompile> {
            options.encoding = Charsets.UTF_8.name()
        }

        withType<Javadoc> {
            options.encoding = Charsets.UTF_8.name()
        }
    }
}

dependencies {
    compileOnly("com.alttd:Galaxy-API:1.18.2-R0.1-SNAPSHOT")
    compileOnly("com.github.milkbowl:VaultAPI:1.7") {
        exclude("org.bukkit","bukkit")
    }
    compileOnly("com.github.TechFortress:GriefPrevention:16.17.1")

    compileOnly("org.projectlombok:lombok:1.18.24")
    annotationProcessor("org.projectlombok:lombok:1.18.24")
}

fun gitCommit(): String {
    val os = ByteArrayOutputStream()
    project.exec {
        commandLine = "git rev-parse --short HEAD".split(" ")
        standardOutput = os
    }
    return String(os.toByteArray()).trim()
}

bukkit {
    name = rootProject.name
    main = "$group.${rootProject.name}"
    version = "${rootProject.version}-${gitCommit()}"
    apiVersion = "1.18"
    authors = listOf("destro174")
    depend = listOf("Vault")
}