PlayerUtils/build.gradle.kts

plugins {
    id("java")
    id("maven-publish")
    id("com.github.ben-manes.versions") version "0.52.0"
}

group = "com.alttd"
version = System.getenv("BUILD_NUMBER") ?: "1.0-SNAPSHOT"
description = "Altitude's Transfer Items plugin"

apply<JavaLibraryPlugin>()

tasks {
    withType<JavaCompile> {
        options.encoding = Charsets.UTF_8.name()
    }

    withType<Javadoc> {
        options.encoding = Charsets.UTF_8.name()
    }

    jar {
        archiveFileName.set("${rootProject.name}.jar")
    }

    processResources {
        filteringCharset = Charsets.UTF_8.name()
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
        filesMatching("plugin.yml") {
            expand(Pair("version", project.version))
        }
    }
}

dependencies {
    compileOnly("com.alttd.cosmos:cosmos-api:26.2.build.17-stable")

    implementation("org.slf4j:slf4j-api:2.0.17")

    compileOnly("org.projectlombok:lombok:1.18.38")
    annotationProcessor("org.projectlombok:lombok:1.18.38")

    implementation(platform("com.intellectualsites.bom:bom-newest:1.56"))
    compileOnly("com.intellectualsites.plotsquared:plotsquared-core")
    compileOnly("com.intellectualsites.plotsquared:plotsquared-bukkit") { isTransitive = false }
}